新闻  |   论坛  |   博客  |   在线研讨会
基于ARM的除法运算初探
lionwq | 2008-01-22 13:01:08    阅读:5880   发布文章
ARM每有除法指令,若程序中涉及到了“/”或“%”运算时,编译器将自动的调用库函数“__rt_udiv”和“__rt_sdiv”来实现该运算。但直接利用C库函数中的标准整数除法程序,根据执行情况和输入操作数的范围,要花费20~100个周期,消耗较多的软件运行时间。对于实时性要求很高的嵌入式系统而言,这是没法忍受了。笔者根据标准的库函数,用ARM的汇编程序实现了“__rt_udiv”和“__rt_sdiv”的功能。
 
  AREA    Divarth, CODE, READONLY
      
        EXPORT __rt_udiv
        EXPORT __rt_sdiv
;/***************************************************************/
;求除数需要移位的次数,为简化除法
;/***************************************************************/
Myclz
        mov r1,#32
Myclzstr
        cmp r0,#0
        bmi Myclzret
        add r0,r0,r0
        subs r1,r1,#1
        bne Myclzstr
Myclzret
        rsb r0,r1,#32
        mov pc,lr
;/***************************************************************/
; name : __rt_udiv
 
; in : r0 除数
;      r1 被除数
; out:r0  = r1/r0
;      r1  = r1%r0
;/***************************************************************/
__rt_udiv
          cmp  r0, #0
          IMPORT  __rt_div0  ;除数为零函数由c语言编写
          beq  __rt_div0
          cmp  r0, r1
          movhi r0, #0
          movhi pc,lr
          stmfd sp!, { r4-r7,lr}
          mov  r4, r1
          mov  r5, r0
          bl Myclz
          mov r7, r0
          mov r0,r4
          bl Myclz
          sub r7,r7,r0
          mov r5,r5,lsl r7
          mov  r0,#0
__rt_udiv_1
          add r0,r0,r0
          subs r1,r4,r5
          movhs r4,r1
          addhs r0,r0, #1
          mov   r5,r5,lsr #1
          subs  r7,r7,#1
          bcs  __rt_udiv_1
          mov r1,r4
          ldmfd sp!,{r4-r7,pc}
;/***************************************************************/
; name : __rt_sdiv
 
; in : r0 除数
;      r1 被除数
; out:r0  = r1/r0
;      r1  = r1%r0
;/***************************************************************/
__rt_sdiv 
          mov r2,#0
          cmp r0,#0
          addlt r2,r2,#1
          rsblt r0,r0,#0
          cmp  r1,#0
          addlt r2,r2,#2
          rsblt r1,r1,#0
          cmp r2,#0
          beq __rt_udiv
          stmfd sp!,{r2,lr}
          bl __rt_udiv
          ldmfd sp!,{r2}
          cmp r2,#2
          rsble r0,r0,#0
          rsbge r1,r1,#0
          ldmfd sp!, {pc}
        END
参与讨论
登录后参与讨论
淡泊以明志 宁静以致远
推荐文章
最近访客